5 PRINT"[147]":POKE53281,0:POKE53280,0
10 D=10:BD=10:REM VALUES FOR DELAYS
15 S=0:REM SOUND IS OFF
20 X=0:Y=10:REM CO-ORDINATES OF START                   OF TEXT
30 A$="WELCOME TO LETTERPRINT BY STEVEN HAMMOND":REM TEXT GOES IN A$
40 P$="BN1D11":REM PARAMETERS GO IN P$
50 GOSUB50000:REM CALL THE PRINT ROUTINE
60 GOSUB1000:REM CALL DELAY BETWEEN                      PRINTS
70 A$="THIS IS A VERSATILE PROGRAM"
80 X=7:Y=10:P$="WN0N11":GOSUB50000:GOSUB1000
90 A$="TO ALLOW YOU TO PRINT TEXT ON THE SCREEN"
100 X=0:Y=10:P$="RN0N00":GOSUB50000:GOSUB1000
110 A$="IN A VARIETY OF MANNERS"
120 X=8:Y=10:D=40:P$="WU0N00":GOSUB50000
125 FORT=1TO1000:NEXTT
130 A$="IN A VARIETY OF MANNERS"
140 X=8:Y=10:D=40:P$="WD0N00":GOSUB50000:PRINT"[147]":D=10
150 A$="THERE ARE MANY THINGS TO CHANGE"
160 X=5:Y=10:P$="GN0N00":GOSUB50000:GOSUB1000
170 A$="SUCH AS POSITION ON SCREEN"
180 X=0:Y=0:P$="BN0N00":GOSUB50000:GOSUB1010
190 A$="WHETHER PRINTED A BIT AT A TIME"
200 X=0:Y=3:P$="BN0N10":GOSUB50000:GOSUB1010
210 A$="WITH A CURSOR"
220 X=0:Y=5:P$="BN0N11":GOSUB50000:GOSUB1010
230 A$="WITH A CURSOR OF YOUR CHOICE"
240 X=0:Y=7:P$="BN0N11[175]":GOSUB50000:GOSUB1010
250 A$="WITH A LINE"
260 X=0:Y=9:P$="BN1N11":GOSUB50000:GOSUB1010
270 A$="OR A FADING LINE"
280 X=0:Y=12:P$="WN1D11":GOSUB50000:GOSUB1010
290 A$="YOU CAN HAVE THE TEXT SLOW"
300 X=0:Y=14:P$="GN0N11":BD=50:GOSUB50000:GOSUB1010
310 A$="OR VERY FAST IF YOU LIKE"
320 X=0:Y=16:P$="GN0N11":BD=2:GOSUB50000:GOSUB1010
330 A$="AND OF COURSE IN A CHOICE OF COLOURS"
340 BD=10:X=0:Y=18:P$="RD0N00":GOSUB50000:GOSUB1000
350 A$="AND WITH SOUND SHOULD YOU NEED IT":X=0:Y=0:P$="GN0N10":S=1:GOSUB50000
360 S=0:GOSUB1000
370 A$="DEMONSTRATION OVER":X=10:Y=10:P$="":GOSUB50000
999 GOTO999
1000 FORT=1TO1000:NEXTT:PRINT"[147]":RETURN
1010 FORT=1TO1000:NEXTT:RETURN
50000 IFP$=""THENP$="WN1D1N"
50005 C$=LEFT$(P$,1):F$=MID$(P$,2,1)
50010 L=VAL(MID$(P$,3,1))
50020 IFL=1THENBAT=VAL(MID$(P$,5,1)):LF$=MID$(P$,4,1)
50030 IFL=0THENBAT=VAL(MID$(P$,5,1)):LF$=MID$(P$,4,1)
50040 IFBAT=1ANDL=1THENCU=VAL(MID$(P$,6,1))
50050 IFBAT=1ANDL=0THENCU=VAL(MID$(P$,6,1))
50070 IFCU=1ANDL=0THENCT$=MID$(P$,7,1)
50080 IFCU=1ANDL=1THENCT$=MID$(P$,7,1)
50085 IFCT$=""THENCT$=" [146]"
50086 F1$=F$
50090 IFC$="W"ANDF$="U"THENCO$="[151][152][155]"
50100 IFC$="W"ANDF$="D"THENCO$="[155][152][151]"
50105 IFC$="W"ANDLF$<>"N"THENG$="[155][152][151]"
50110 IFC$="B"ANDF$="U"THENCO$="[154][159]"
50120 IFC$="B"ANDF$="D"THENCO$="[159][154]"
50125 IFC$="B"ANDLF$<>"N"THENG$="[159][154]"
50130 IFC$="G"ANDF$="U"THENCO$="[153]"
50140 IFC$="G"ANDF$="D"THENCO$="[153]"
50145 IFC$="G"ANDLF$<>"N"THENG$="[153]"
50150 IFC$="R"ANDF$="U"THENCO$="[150]"
50160 IFC$="R"ANDF$="D"THENCO$="[150]"
50165 IFC$="R"ANDLF$<>"N"THENG$="[150]"
50170 IFC$="Y"ANDF$="U"THENCO$="[129][158]"
50180 IFC$="Y"ANDF$="D"THENCO$="[158][129]"
50182 F$=F1$
50185 IFC$="Y"ANDLF$<>"N"THENG$="[158][129]"
50190 K$="[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
50200 Y$=""
50210 LI$=LEFT$(K$,LEN(A$))
50212 V$=LEFT$(Y$,Y)
50215 IFBAT=1THEN50240
50220 IFF$="N"THENGOSUB50400:GOSUB50450
50230 IFF$<>"N"THENGOSUB50500
50240 IFCU=0ANDBAT=1THENGOSUB50600
50250 IFCU=1ANDBAT=1THENGOSUB50700
50260 IFL=0THENRETURN
50270 IFLF$="U"THENGOSUB51000
50275 IFLF$="D"THENGOSUB50800
50280 IFLF$="N"THENGOSUB50400:GOSUB50900
50395 RETURN
50400 IFC$="W"THENCO$="[151]"
50410 IFC$="B"THENCO$=""
50420 IFC$="G"THENCO$=""
50430 IFC$="R"THENCO$=""
50440 IFC$="Y"THENCO$=""
50445 RETURN
50450 PRINT"";TAB(X);V$;CO$;A$:RETURN
50500 FORK=1TO4:PRINT"";TAB(X);V$;MID$(CO$,K,1);A$
50510 FORT=1TOD:NEXTT
50520 NEXTK:RETURN
50600 PRINT"";TAB(X);V$;:GOSUB50400:PRINTCO$;
50605 FORK=1TOLEN(A$)
50610 PRINTMID$(A$,K,1);:FORT=1TOBD:NEXTT:IFS=1THENGOSUB51100
50620 NEXTK:RETURN
50700 PRINT"";TAB(X);V$;:GOSUB50400:PRINTCO$;
50705 FORK=1TOLEN(A$)
50710 PRINTMID$(A$,K,1);CT$;"[157]";:FORT=1TOBD:NEXTT
50720 IFS=1THENGOSUB51100
50730 NEXTK:PRINT" ":RETURN
50800 FORK=1TO4:PRINT"";TAB(X);V$;"";MID$(G$,K,1);LI$
50810 FORT=1TOD:NEXTT
50820 NEXTK:RETURN
50900 PRINT"";TAB(X);V$;"";LI$:RETURN
51000 FORK=4TO1STEP-1:PRINT"";TAB(X);V$;"";MID$(G$,K,1);LI$
51010 FORT=1TOD:NEXTT
51020 NEXTK:RETURN
51100 POKE54296,8:POKE54296,0:RETURN